<? Zelda Theme - inspired by piano arrangement by Shinobu Amayake ?>

130 => )

.alice     <0,3,5> => @detune pp
.bob       <0,3,5> => @detune pp
.bass    @sawpulse => @instrument p o~~~~
.hats        @hats => @instrument pp
.snare      @snare => @instrument mp
.kick        @kick => @instrument mp

{! four_bars_rest  !! }}}}}  !}
{! eight_bars_rest !! }}}}}} !}

{! bass_end<x>    !! !x ) ) ) ] ]     !}
{! bass_climb     !! | _e ]] _a# ]] c# ]  e ]] a# ]] ~o c# ] e ) } | f ) o~ _f ]] ]] ] ) } | !}

{! bassline_a !!
  <a#, g#, f#, c#, b, a#, c>.{: ) ]] ]] ] ) ) :}
  !bass_end<f>
!}

{! bassline_b !!
  <a#, g#, f#, f>.{: ) ]] ]] ] ) ) :}

  !bass_climb !bass_climb

  <b, a#, c     >.{: ) ]] ]] ] ) ) :} !bass_end<f>
!}

{! intro !!

  .hats  !four_bars_rest
  .snare !four_bars_rest
  .kick  !four_bars_rest

  .alice | _a# ))        o/. ]]  ]] ]] ] |     ]. _g#  ]] _a# )        o/.  ]]  ]] ]] ] |
  .bob   | _d  ))        o/. ]]  ]] ]] ] | _c  ].      ]]     )        o/.  ]]  ]] ]] ] |
  .bass  |  a# ) ]] ]] ] )       ]] ]] ] |  g# )              ]] ]] ]  )        ]] ]] ] |

  .alice |     ]. _g# ]] _a# )       o/. ]] ]] ]] ] |   ]    _f ]] ]]  ] ]] ]]  ] ]] ]]  ]     ] |
  .bob   | _c# ].     ]]     )       o/. ]] ]] ]] ] |   ] o~ _a ]] ]]  ] ]] ]]  ] ]] ]]  ]     ] |
  .bass  |  f# )             ]] ]] ] )      ]] ]] ] | f )              )        )      g ]   a ] |
!}

{! melody_a !! .bass !bassline_a

  .alice | _a# ) _f )__          o/. _a# ]]  ]]   c ]]  d ]] d# ]] |
  .bob   | _d  )    ]] ]] _c ] _d ].     ]]  ]] _d# ]] _f ]] _g ]] |

  .alice |  f  ))                             o/ ]   f ]  f# ]] g# ]] |
  .bob   | _g# ]. _a# ]] ]] c ]] d ]] d# ]] f )    _g# ] _a# ]] c  ]] |

  .alice |  a# ))                                  o/ a# ]  ]  g# ]]  f# ]] |
  .bob   |  c# ]. _f# ]]  ]] _g# ]] _a# ]] c ]] c# ]. ]]    ]  c  ]] _a# ]] |

  .alice | g# ].  f# ]]  f ))                      )               |
  .bob   | c# ]. _g# ]]    ]] ]] _f# ]  _g# ]. ]]  ]] _f# ]] _g# ] |

  .alice |  d# ] ]]  f ]]  f# ))                   f ] d#  ] |
  .bob   | _f# ] ]] _f ]] _f# ] ]] _g# ]]  _a# ) _g# ] _f# ] |

  .alice |  c# ] ]]  d# ]]  f ))                 d# ]  c# ] |
  .bob   | _f  ] ]] _d# ]] _f ] ]] _f# ]] _g# ) _f# ] _d# ] |

  .alice |  c ] ]]  d ]]  e ))                   g )     |
  .bob   | _e ] ]] _d ]] _e ] ]] _g ] ]] _a ]] _a# ] c ] |

  .alice |  f ]     _f ]] ]]  ] ]] ]]   ] ]] ]]   ]  ]    |
  .bob   | _a ] o~  _a ]] ]]  ] ]] ]]   ] ]] ]]   ]  ] ~o |

!}

{! melody_b !! .bass !bassline_b

  .alice | _a# ) _f )__          o/. _a# ]]  ]]   c ]]  d ]] d# ]] |
  .bob   | _d  )    ]] ]] _c ] _d ].     ]]  ]] _d# ]] _f ]] _g ]] |

  .alice |  f  ))                             o/ ]   f ]  f# ]] g# ]] |
  .bob   | _g# ]. _a# ]] ]] c ]] d ]] d# ]] f )    _g# ] _a# ]] c  ]] |

  .alice | a# )). ~o c# ) | c  ) o~ a )) f  ) |  f# )).  a# ) | a )  f )) ) |
  .bob   | c# )).    e  ) | d# )    c )) _a ) | _b  )).  c# ) | c ) _a )) ) |

  .alice |  f# )). a# ) | a )  f )) d ) |  d# )).  f# ) |  f  )  c# )) _a# ) |
  .bob   | _b  )). c# ) | c ) _a ))   ) | _f# )). _b  ) | _a# ) _f  )) _c# ) |

  .alice |  c ] ]]  d ]]  e ))                        g  )     |
  .bob   | _e ] ]] _d ]] _e ] ]] _f ]] _g ] ]] _a ]] _a# ] c ] |

  .alice |  f ]    _f ]] ]]  ] ]] ]]   ] ]] ]]   ]  ]    |
  .bob   | _a ] o~ _a ]] ]]  ] ]] ]]   ] ]] ]]   ]  ] ~o |

!}

{! fill !!
  .alice |  f ]    _f ]] ]]  ] ]] ]]   ] ]] ]]   ]  ]    |
  .bob   | _a ] o~ _a ]] ]]  ] ]] ]]   ] ]] ]]   ]  ] ~o |
  .snare |    ]       ]] ]]  ] ]] ]]   ] ]] ]]   ]  ]    |
  .hats  |    ]       ]      ] ]       ] ]       ]  ]    |
  .kick  |    )              }         )         }       |
  .bass !bass_end<f>
!}

{! drums !!
  .hats  {: ] ] ] ] ] ] ] ]] ]] :: !i <= 11 :}
  .kick  {: ) } ) } :: !i <= 11 :}
  .snare {: } ) } ) :: !i <= 10 :} | ] ]] ]]  ] ]] ]]  ] ]] ]]  ]  ] |
!}

!intro !melody_a

.kick !eight_bars_rest
.hats !four_bars_rest }}} }}} }}} ] ] ] ] ] ] ] ]
.snare !eight_bars_rest

!fill !melody_b !drums !fill

__beats_______________   __rests_______________

))) - whole               }}} - whole
))  - half                 }} - quarter
)   - quarter               } - quarter
]   - eighth               o/ - eighth
]]  - sixteenth           oo/ - sixteenth
]]] - thirty secondth    ooo/ - thirthy secondth

).  - dotted quarter
]]. - dotted sixteenth
o/. - dotted eighth rest

.)   - staccato quarter
.]]. - staccato and dotted sixteenth

)__  - quarter with a tie (ties to the next beat)
)__. - dotted quarter with a tie

<? use # or b after the noat to sharp or flat it. Or use scale degree numbers. ?>

c ) d ) eb ) f ]] ]] g ] ] g# )

<? you get two octaves to work with, prepend _ for the lower octave. ?>

<_c, _d, _e, _f, _g, _a, _b, c, d, e, f, g, a, b>.choose ]]

A Am A#m Asus2 Adim etc..

<_a,c,e> )  <_a,c#,e> )

<? up one octave ?>    <? down one ?>
~o                     o~
8va                    8vb
ottava alta            ottava bassa

<? up two ?>           <? down two ?>
~~o                    o~~
15ma                   15mb
alla quindicesima

fff ffforte ppp pppiano piano mp mf ff pp p sfp

|: _a ]]] c ]]] e ]]] :| g ]]] ooo/ ]]] :|

| _a ) c ) e ) | ,segno` ) ]] ]] e ]] | f D.S. al fine ) ) ) fine

| ,segno` c ]] e ]] (+) ]] ]] D.S. al Coda '.......'  (+) | a) c) e) } |

<? from the top ?>
| _a] c] e] | D.C. <? also accept Da Capo ?>

<? from the segno ?>
| _a] c] e] o/ | ,segno` _f] f] _f] o/ Dal Segno |

|: c )) ) | [1.] _a] c] a]] e]] :| [2.]  ]] ]] _c) ||

<? names of things start with @ ?>
@smooth => @instrument
<0,3,5> => @detune

<? to lookup the values, we use ! in place of @.... more on ! below.. ?>
a# => @foo
!foo )

{: ]] oo/ ]] ]] :: !x <= !y :} 

<_a, _c, c, _e, e, _a>.{: ] ]] ]] :}

<_a, _c, c, _e, e, _a>.{: ] ]] ]] :: !groovy == 5 :}

<? executes 8 times ?>
{: <_a, _c, _e, a>.choose ]] ]] ] :: !i <= 8:}

{? !x == !y ?? ]]] ?}

{? !x == !y ?? ]]] ?? ooo/ ?}

{! name<args> !!
  body
  ...
!! stinger !}

{! zorp<derp> !!
 | )         }             |
 | )         ]] oo/ ]      |
 | ]    ]    ]] ]]  ]      |
 | ]    ]    ]] ]]  oo/ ]] |
!! !derp.choose !}

<? - this calls !zorp.choose, setting @derp to <_a, c#, e>
   - !derp.choose in the stinger, means it will pick one noat from @derp each beat.
   - the !zorp.choose will choose one line at random ?>
!zorp<<_a, c#, e>>.choose

<_a, c#, e> => @A

!zorp<!A>.next   <? plays | ) }        | ?>
!zorp<!A>.next   <? plays | ) ]] oo/ ] | ?>
!zorp<!A>.last   <? plays | ) }        | ?>

{! alice !! ~o mp
  <c#, e, _a, g#> => @favorites
          <0,5,7> => @detune
            @acid => @instrument
!}

{! bob<x> !! o~~ forte
  @bass => @instrument
     !x => @favorites
!}

{! <x> !! <0, 4, !x> => @detune !} => @charlie

.a !alice.inline
.b !bob<<a,e>>.inline
.c !charlie<<5,7,9>.choose>.inline
...

<c, e, g> => @food

!food.next )   <? plays: c ?>
!food.next )   <? plays: e ?>
!food.last )   <? plays: c ?>
!food.choose ) <? at random ?>

<? save into @food, a random number between zero and five ?>
5.rand => @food

<? print foo to the post screen ?>
'foo'.postln

<? choose a random note and post it to the screen ?>
<c,d,e,f,g,a,b>.choose.postln

!Array.fib<20,27,3> => @food

!MyRediculousClass.new<'srsly', 2.1828> => @zagwaggler

!zagwaggler.bringTheWub<'wub'>.wub.wub.wub.wub

^^(;,;)^^

^^(;!octave == 5;)^^